文章目录

• 1. ESP8266 建立网络服务器
• 2. 通过网络服务器对NodeMCU开发板进行控制
• 写在最后

1. ESP8266 建立网络服务器

注意：默认情况下我们的浏览器或者手机都是使用80端口来访问服务器的

#include <ESP8266WiFi.h>        // 本程序使用 ESP8266WiFi库
#include <ESP8266WiFiMulti.h>   //  ESP8266WiFiMulti库
#include <ESP8266WebServer.h>   //  ESP8266WebServer库
 
ESP8266WiFiMulti wifiMulti;     // 建立ESP8266WiFiMulti对象,对象名称是'wifiMulti'
 
ESP8266WebServer esp8266_server(80);// 建立ESP8266WebServer对象，对象名称为esp8266_server
                                    // 括号中的数字是网路服务器响应http请求的端口号
                                    // 网络服务器标准http端口号为80，因此这里使用80为端口号
 
void setup(void){
  Serial.begin(9600);          // 启动串口通讯
 
  //通过addAp函数存储  WiFi名称       WiFi密码
  wifiMulti.addAP("Duer", "duer123456");  
  wifiMulti.addAP("aaaa", "87654321"); 
  wifiMulti.addAP("bbbb", "13572468"); 
                                                // 此处WiFi信息只是示例，请在使用时将需要连接的WiFi信息填入相应位置。
                                                // 另外这里只存储了3个WiFi信息，您可以存储更多的WiFi信息在此处。
 
  int i = 0;                                 
  while (wifiMulti.run() != WL_CONNECTED) {  // 通过wifiMulti.run()，NodeMCU将会在当前
    delay(1000);                             // 环境中搜索addAP函数所存储的WiFi。如果搜到多个存储的WiFi那么NodeMCU
    Serial.print(i++); Serial.print(' ');    // 将会连接信号最强的那一个WiFi信号。
  }                                          // 一旦连接WiFI成功，wifiMulti.run()将会返回“WL_CONNECTED”。这也是
                                             // 此处while循环判断是否跳出循环的条件。
 
  // WiFi连接成功后将通过串口监视器输出连接成功信息 
  Serial.println('\n');                     // WiFi连接成功后
  Serial.print("Connected to ");            // NodeMCU将通过串口监视器输出。
  Serial.println(WiFi.SSID());              // 连接的WiFI名称
  Serial.print("IP address:\t");            // 以及
  Serial.println(WiFi.localIP());           // NodeMCU的IP地址
  
//--------"启动网络服务功能"程序部分开始-------- 
  esp8266_server.begin();                   
  esp8266_server.on("/", handleRoot);       	//  访问转接处理
  esp8266_server.onNotFound(handleNotFound);    // 如果在MCU中找不到这个页面    
//--------"启动网络服务功能"程序部分结束--------
  Serial.println("HTTP esp8266_server started");//  告知用户ESP8266网络服务功能已经启动
}

void loop(void){
  esp8266_server.handleClient();     // 处理http服务器访问
}

void handleRoot() {   //处理网站根目录“/”的访问请求 
  esp8266_server.send(200, "text/plain", "Hello from ESP8266");   // NodeMCU将调用此函数。
}
 
// 设置处理404情况的函数'handleNotFound'
void handleNotFound(){                                        // 当浏览器请求的网络资源无法在服务器找到时，
  esp8266_server.send(404, "text/plain", "404: Not found");   // NodeMCU将调用此函数。
}

• esp8266_server.on("/", handleRoot); 当我们的浏览器访问首页的时候，使用handleRoot函数提供首页信息

• esp8266_server.onNotFound(handleNotFound);当访问的页面不存在的时候，调用handleNotFound函数处理这个访问

• handleRoot函数

  esp8266_server.send：使用网络服务器对象发送信息

  200:向浏览器发送状态码，表示已经成功收到请求

  text/plain:发送方服务器将要发送一个纯文本(text:文本， plain: 纯, 也可以发送html)

  "Hello from ESP8266"：需要发送的文本信息

• handleClient():处理浏览器客户端，只要有浏览器请求，就要响应

1. 运行并上传代码，有结果如下

2. 在浏览器中打开页面

​ 正确返回文本信息

3. 如果输入一个完全不存在的页面

显示不存在信息

2. 通过网络服务器对NodeMCU开发板进行控制

#include <ESP8266WiFi.h>        // 本程序使用 ESP8266WiFi库
#include <ESP8266WiFiMulti.h>   //  ESP8266WiFiMulti库
#include <ESP8266WebServer.h>   //  ESP8266WebServer库
 
ESP8266WiFiMulti wifiMulti;     // 建立ESP8266WiFiMulti对象,对象名称是 'wifiMulti'
 
ESP8266WebServer esp8266_server(80);// 建立网络服务器对象，该对象用于响应HTTP请求。监听端口（80）
 
void setup(void){
  Serial.begin(9600);   // 启动串口通讯
 
  pinMode(D4, OUTPUT); //设置内置LED引脚为输出模式以便控制LED
  
  //通过addAp函数存储  WiFi名称       WiFi密码
  wifiMulti.addAP("Duer", "duer123456");  // 这三条语句通过调用函数addAP来记录3个不同的WiFi网络信息。
//  wifiMulti.addAP("CMCC-yLaQ", "1123456"); // 这3个WiFi网络名称和密码
//  wifiMulti.addAP("taichi-maker3", "13572468");
                                                // 此处WiFi信息只是示例，请在使用时将需要连接的WiFi信息填入相应位置。
                                                // 另外这里只存储了3个WiFi信息，您可以存储更多的WiFi信息在此处。
  Serial.println("正在连接Wifi,请稍等：");  
  int i = 0;                                 
  while (wifiMulti.run() != WL_CONNECTED) {  // 此处的wifiMulti.run()是重点。通过wifiMulti.run()，NodeMCU将会在当前
    delay(1000);                             // 环境中搜索addAP函数所存储的WiFi。如果搜到多个存储的WiFi那么NodeMCU
    Serial.print(i++); Serial.print(' ');    // 将会连接信号最强的那一个WiFi信号。
  }                                          // 一旦连接WiFI成功，wifiMulti.run()将会返回“WL_CONNECTED”。这也是
                                             // 此处while循环判断是否跳出循环的条件。
  
  // WiFi连接成功后将通过串口监视器输出连接成功信息 
  Serial.println('\n');
  Serial.print("Connected to ");
  Serial.println(WiFi.SSID());              // 通过串口监视器输出连接的WiFi名称
  Serial.print("IP address:\t");
  Serial.println(WiFi.localIP());           // 通过串口监视器输出ESP8266-NodeMCU的IP
 
  esp8266_server.begin();                           // 启动网站服务
  esp8266_server.on("/", HTTP_GET, handleRoot);     // 设置服务器根目录即'/'的函数'handleRoot'
  esp8266_server.on("/LED", HTTP_POST, handleLED);  // 设置处理LED控制请求的函数'handleLED'
  esp8266_server.onNotFound(handleNotFound);        // 设置处理404情况的函数'handleNotFound'
 
  Serial.println("HTTP esp8266_server started");//  告知用户ESP8266网络服务功能已经启动
}
 
void loop(void){
  esp8266_server.handleClient();                     // 检查http服务器访问
}
 
void handleRoot() {       
  esp8266_server.send(200, "text/html", "<form action=\"/LED\" method=\"POST\"><input type=\"submit\" value=\"LED\"></form>");
}
 
//处理LED控制请求的函数'handleLED'
void handleLED() {                          
  digitalWrite(D4,!digitalRead(D4));// 改变LED的点亮或者熄灭状态
  esp8266_server.sendHeader("Location","/");          // 跳转回页面根目录
  esp8266_server.send(303);                           // 发送Http相应代码303 跳转  
}
 
// 设置处理404情况的函数'handleNotFound'
void handleNotFound(){
  esp8266_server.send(404, "text/plain", "404: Not found"); // 发送 HTTP 状态 404 (未找到页面) 并向浏览器发送文字 "404: Not found"
}

• esp8266_server.on("/", HTTP_GET, handleRoot):使用GET方式请求浏览器

• esp8266_server.on("/LED", HTTP_POST, handleLED);:使用POST方式调用handleLED函数

• esp8266_server.send:

• 200:收到信息

• "text/html":类型是html代码

  <form action=\"/LED\" method=\"POST\">
      <input type=\"submit\" value=\"Toggle LED\">
  </form>
  

  • 当用户按下按键以后，给服务器发送一个请求，请求的方式是POST，提交的页面是LED
  • 直到程序没有看到反斜杠，才说明哪些是C语言的双引号

• digitalWrite(LED_BUILTIN,!digitalRead(LED_BUILTIN));: 改变LED的点亮或者熄灭状态

• esp8266_server.sendHeader("Location","/");:跳转回首页

写在最后

注：本专栏实验均使用免费的仿真平台TinkerCAD，传送门如下

传送门:ThinkerCAD

代码参考案例NodeMCU开发板的无线终端模式by太极创客

各位看官，都看到这里了，麻烦动动手指头给博主来个点赞8，您的支持作者最大的创作动力哟！
＜（＾－＾）＞
才疏学浅，若有纰漏，恳请斧正
本文章仅用于各位同志作为学习交流之用，不作任何商业用途，若涉及版权问题请速与作者联系，望悉知