一、面板数据与模型

1.面板数据分类

（1）短面板（N>T）和长面板(N<T) （2）动态面板(解释变量包含被解释变量的滞后值）和静态面板 （3）平衡面板（每个个体在相同的时间内都有观测值）和非平衡面板

2.面板数据模型

（1）非观测效应模型（存在不可观测的个体效应模型）

• 固体效应模型（fixed effects model,fe）

• 随机效应模型 (random effects model,re)

• 选择fe还是re，用hausman检验。Help hausman查看用法，例如： . xtreg ln_wage age msp ttl_exp, fe . estimates store fixed . xtreg ln_wage age msp ttl_exp, re . hausman fixed ., sigmamore

（2）混合回归模型（不存在不可观测的个体效应模型）

二、面板数据模型估计及标准误的修正

1.面板数据模型的估计方法

（1）固定效应模型

• 固定效应变化（组内变换）

• stata命令：xtreg y x ,fe

• 引入时间效应的双向固定效应的stata命令：xi:xtreg y x i.year,fe 其中i.year直接生成了年份的虚拟变量，控制了时间效应。 另外，也可以通过 tab year,gen(year)这一命令生成年份的虚拟变量。

LSDV

• 将不可观测的个体效应 αi看做待估计的参数， αi 就是第i个个体的截距

• 估计n个截距的方法就是引入n-1个虚拟变量（如果省略常数项，则引入n个虚拟变量）

• 如果不存在时间效应：xi:reg y x i.code 其中i.code直接生成了个体的虚拟变量

• 如果存在时间效应：xi:reg y x i.code i.year

（2）随机效应模型估计

• GLS

• Stata命令：xtreg y x ,re

• 双向控制，xi:xtreg y x i.year,re

三、短面板数据分析的基本程序

1.简介

（1）以检验啤酒税将降低交通死亡率的假说为例[美国48个州，1982-1988年的数据] （2）模型设定与数据 （3）变量：

• 被解释变量：fatal（交通死亡率）

• 核心解释变量：beertax（啤酒税）

• 可观测的控制变量：spircons（酒精的消费量）、unrate（失业率）、perinck（人均收入）

• μi：不可观测的个体效应

• γt：时间效应

2.基本流程

（一）模型设定与数据

1.查看数据： des 2.查看面板数据特征： xtdes Xtdes给出面板数据的特征。本例中，判断为短面板数据 3.将数据设为面板数据格式： xtset state year xtset 个体变量 时间变量(告诉stata，这是面板数据），如本例中写 xtset state year （二）描述性统计与作图

1.描述性统计（sum+关键变量名）： sum fatal beertax spircons unrate perinck 2.画出关键变量与被解释变量的散点图和回归直线： twoway (scatter fatal beertax) (lfit fatal beertax) 符号与理论上相反，可能的原因：没有控制其他变量。 后面昨晚LSDV估计后，用avplot命令画出二者的偏回归图（控制了其他变量。） 3.生成年份虚拟变量： tab year, gen(year) 4.LSDV回归： reg fatal beertax spircons unrate perinck year2-year7 i.state

【3，4步骤可合并成： reg fatal beertax spircons unrate perinck i.year i.state 】

5.画出关键变量与被解释变量的偏回归图： avplot beertax 6.画出所有解释变量与被解释变量的偏回归图： avplots 7.画出关键变量的时间序列图 ： xtline fatal 8.画出关键变量的时间序列图： xtline beertax （三）模型的选择

1.比较混合回归模型和固定效应模型： xtreg fatal beertax spircons unrate perinck year2-year7,fe

1. PLS or FE？ 2.tab year,gen(year) 3.在使用命令“xtreg,fe”时，如果不加选项cluster(state),则输出结果还包含一个F检验，其原假设为“H0:all μi=0”，若拒绝原假设，则选择固定效应模型。

2.安装xtcsd命令： ssc install xtcsd 3.检验截面相关问题：

• xtcsd,pes xtcsd,fri xtcsd,fre

xtcsd命令只有在运行完fe或re回归后，才能使用

4.安装命令： ssc install xtscc 5.（存在截面相关问题时）处理了误差项截面相关问题的LSDV估计： xi:xtscc fatal beertax spircons unrate perinck year2-year7 i.state 6.（存在截面相关问题时）对州虚拟变量做F检验： testparm _Istate* 7.（不存在截面相关问题时）使用聚类到州获得的标准误处理自相关和异方差问题： xi:reg fatal beertax spircons unrate perinck year2-year7 i.state, cluster(state) 8.（不存在截面相关问题时）对州虚拟变量做F检验： testparm _Istate*

（四）比较固定效应模型fe和随机效应模型re

1.（Husman检验）固定效应估计： xtreg fatal beertax spircons unrate perinck year2-year7, fe 2.（Husman检验）存储固定效应估计的结果： est store FE 3.（Husman检验）随机效应估计： xtreg fatal beertax spircons unrate perinck year2-year7, re 4.（Husman检验）将两个估计结果进行比较(hausman 检验，如果P值小于0.05，则表示拒绝原假设。用fe更合适： hausman FE ., sigmamore

5. hausman FE ., sigmaless

3.报告计量结果

• 由于之前的hausman 检验选择了fe模型，所以要报告固定效应模型的估计结果，同时要解决误差项可能存在的自相关、异方差和截面相关问题。

• 前面xtcsd检验表明存在截面相关。

（一）假设选择固定效应模型 1.固定效应模型估计： xtreg fatal beertax spircons unrate perinck year2-year7, fe 2.检验截面相关问题 xtcsd,pes abs xtcsd,fri abs xtcsd,fre abs （二）如果不存在截面相关，检验是否存在异方差 1.安装xttest3： ssc install xttest3

2. xtreg fatal beertax spircons unrate perinck year2-year7, fe

3. xttest3 （三）自相关检验 1.安装xtserial： search xtserial 2.生成州虚拟变量： tab state,gen(state) 3.完成自相关检验： xtserial fatal beertax spircons unrate perinck state2-state48 year2-year7 （四）最终报告由如下命令估计的结果 这里给出不同解释变量组合，进行回归后的结果保存：

    xtreg fatal beertax spircons unrate perinck year2-year7, fe robust  
    est store result1
    xtreg fatal beertax  unrate perinck year2-year7, fe robust  
    est store result2
    xtreg fatal beertax spircons  perinck year2-year7, fe robust  
    est store result3

（五）结果汇报 1.安装estout命令，esttab是estout的一个命令： ssc install estout 2.结果报告(括号内是t统计量值）： esttab result1 result2 result3 ,se ar2 3.把结果保存到word中(括号内是稳健标准误）： esttab result1 result2 result3 using tab.rtf ,se ar2 4.把结果保存到excel中(括号内是稳健标准误）： esttab result1 result2 result3 using tab.csv ,se ar2 （六）补充

假设选择随机效应模型 xtreg fatal beertax spircons unrate perinck year2-year7, re cluster(state) //对自相关和异方差稳健的随机效应模型估计 xtscc redfatal redbeertax redspircons redunrate redperinck redyear2 redyear3 redyear4 redyear5 redyear6 redyear7 //xtscc可以同时解决三大问题

完整do命令：

    use "D:\administrator\Desktop\互联网金融\第一讲数据及do文件\traffic-original.dta", clear
    des
    xtdes
    xtset state year
    sum fatal beertax spircons unrate perinck
    twoway (scatter fatal beertax) (lfit fatal beertax)
    graph save Graph "D:\administrator\Desktop\Graph.gph"
    twoway (scatter fatal beertax) (lfit fatal beertax)
    tab year, gen(year)
    reg fatal beertax spircons unrate perinck year2-year7 i.state
    avplot beertax
    avplots
    xtline fatal
    xtline beertax
     xtreg fatal beertax spircons unrate perinck year2-year7,fe
    ssc install xtcsd
    xtcsd,pes
    xtcsd,fri
    xtcsd,fre
    ssc install xtscc
    xi:xtscc fatal beertax spircons unrate perinck year2-year7 i.state
    testparm  _Istate*
    xi:reg fatal beertax spircons unrate perinck year2-year7 i.state, cluster(state)
    testparm  _Istate*
    xtreg fatal beertax spircons unrate perinck year2-year7, fe
    est store FE
    xtreg fatal beertax spircons unrate perinck year2-year7, re
    hausman FE ., sigmamore
    hausman FE ., sigmaless
    ssc install xttest3
    xtreg fatal beertax spircons unrate perinck year2-year7, fe
    xtcsd,pes abs
    xtcsd,fri abs
    xtcsd,fre abs
    xttest3
    search xtserial
    tab state,gen(state)
    xtserial fatal beertax spircons unrate perinck state2-state48 year2-year7
    xtreg fatal beertax spircons unrate perinck year2-year7, fe robust
    est store result1
    xtreg fatal beertax  unrate perinck year2-year7, fe robust
    est store result2
    xtreg fatal beertax spircons  perinck year2-year7, fe robust
    est store result3
    ssc install estout
    esttab result1 result2 result3 ,se ar2
    esttab result1 result2 result3 using tab.rtf ,se ar2
    esttab result1 result2 result3 using tab.csv ,se ar2
    xtreg fatal beertax spircons unrate perinck year2-year7, re cluster(state)

—————————————— 写在最后，这是作者对上课内容的整理笔记，点个↓